connector-proxy/build.gradle

plugins {
    id 'application'
}

mainClassName = 'io.connector.Main'
buildDir = 'bin'

def moduleNames = subprojects.findAll {
    it.name.startsWith("connector-module-")
}

dependencies {
    compile project(":connector-app")
}

// create fat JAR
jar {
    manifest {
        attributes "Main-Class": "$mainClassName"
    }

    from {
        configurations.runtimeClasspath.collect {
            it.isDirectory() ? it : zipTree(it)
        }
    }
}

// setting for all projects
allprojects {

    // set that all projects are Java projects
    apply plugin: 'java'

    group 'io.connector'
    version '1.0'

    repositories {
        mavenLocal()
        mavenCentral()
    }

    java {
        sourceCompatibility = JavaVersion.VERSION_1_8
        targetCompatibility = JavaVersion.VERSION_1_8
    }

    dependencies {
        compile group: 'org.apache.logging.log4j', name: 'log4j-api', version: '2.12.0'
        compile group: 'org.apache.logging.log4j', name: 'log4j-core', version: '2.12.0'

        testCompile group: 'org.junit.jupiter', name: 'junit-jupiter-engine', version: '5.8.0-M1'
    }

    task unitTest(type: Test) {
        description = 'Runs JUnit tests.'

        useJUnitPlatform {
            excludeTags 'integration'
        }
    }
}

// settings for all modules
subprojects {
    buildDir = '../bin'
}

project("connector-app") {
    dependencies {
        compile project(":connector-core")
        compile group: 'com.beust', name: 'jcommander', version: '1.78'
    }
}

project(":connector-core") {

    dependencies {
//        compile group: 'io.vertx', name: 'vertx-core', version: '4.0.3'
        compile group: 'io.vertx', name: 'vertx-web', version: '4.0.3'
        compile group: 'org.apache.httpcomponents', name: 'httpclient', version: '4.5.9'
        compile group: 'org.yaml', name: 'snakeyaml', version: '1.24'

        compile group: 'io.vertx', name: 'vertx-junit5', version: '4.0.3'
        compile group: 'com.fasterxml.jackson.core', name: 'jackson-databind', version: '2.12.3'
    }
}

project(":connector-model") {

    dependencies {
        compile group: 'io.vertx', name: 'vertx-core', version: '4.0.3'
    }
}

// settings for all 'connector-module-*'
configure(moduleNames) {

    dependencies {
        compile project(":connector-core")
        compile project(":connector-model")
    }

    task integrationTest(type: Test) {
        description = 'Runs integration tests for ' + project.name

        useJUnitPlatform {
            includeTags 'integration'
        }

        filter {
            includeTestsMatching "io." +project.name.replace("-", ".") + ".*"
        }
    }
}


// settings for each project
project(":connector-module-senslog1") {

    dependencies {
        compile group: 'org.jdbi', name: 'jdbi3-core', version: '3.18.0'
//        compile group: 'org.jdbi', name: 'jdbi3-postgres', version: '3.18.0'
        compile group: 'org.postgresql', name: 'postgresql', version: '42.2.19'
    }
}